[tex-live] [texlive] dviout requires locally installed folder

Siep Kroonenberg siepo at cybercomm.nl
Wed Apr 8 17:17:34 CEST 2009


On Wed, Apr 08, 2009 at 02:14:06PM +0200, Christine Kremsmayr wrote:
>
> I have changed the settings in dviout (Option --> Setup Parameters -->  
> Font). In the first input box I changed the string
> to "C:\Dokumente und  
> Einstellungen\christine\.texlive2008\texmf-var\fonts;H:\PortableApps\TeXLive2008\texmf-var\fonts;H:\PortableApps\TeXLive2008\texmf-dist\fonts;H:\PortableApps\TeXLive2008\texmf\fonts"
>
> Now it works fine.
>
> That means to me: Either the TeXLive 2008 to a USB stick fails (because  
> TeXLive still requires a local folder C:\Dokumjente und  
> Einstellungen\christine\.texlive2008) or dviout has a tiny bug because  
> dviout still requires the local folder.
>
> Please can anyone tell me what's wrong? And what can I do to get TeXLive  
> independant from this local folder?
>
> best regards Christine

1. tl-portable.bat is a TL starter, not a TL installer. So you run
TeXi ONLY by starting tl-portable from a command-prompt, or by
double-clicking its icon. If you want to, you can create modified
copies of tl-portable.bat which start an editor or previewer.

2. For semi-portable use, you can run `install-tl -no-gui' to get an
option to run TL `from dvd'. In the next edition, this option should
also be available from the GUI. This always uses a directory under
%userprofile% for generated files, because if one is already willing
to change environment settings then it doesn't make much sense to
worry about some generated files in the home directory.

3. Another TeX on your searchpath may interfere with
tl-portable.bat. I just fixed this in the repository by prepending
TeX Live to the searchpath at an earlier stage. Below the updated
version:

rem ===============================================

@echo off

rem Copyright 2008 Siep Kroonenberg.
rem You may freely use, modify and/or distribute this file.

rem TeX Live Root; ends with backslash
set TEXDIR=%~dp0
set tldrive=%~d0

rem TEXDIR writable?
set TEXDIRW=%USERPROFILE%\.tlportable2008\
del "%TEXDIR%tl_wrtest" 2>nul
echo Testing for write access %TEXDIR%...
echo Hello >"%TEXDIR%tl_wrtest"
if not exist "%TEXDIR%tl_wrtest" goto wrtestdone
del "%TEXDIR%tl_wrtest"
set TEXDIRW=%TEXDIR%
:wrtestdone
if not exist "%TEXDIRW%" md "%TEXDIRW%"

rem Use TEXMFHOME for private data,
rem TEXMFLOCAL for department- or workgroup data.
rem It is allright if TEXMFLOCAL does not exist.

set TEXMFSYSVAR=%TEXDIRW%texmf-var
if exist "%TEXDIR%texmf-var" set TEXMFSYSVAR=%TEXDIR%texmf-var

set TEXMFSYSCONFIG=%TEXDIRW%texmf-config
if exist "%TEXDIR%texmf-config" set TEXMFSYSCONFIG=%TEXDIR%texmf-config
set TEXMFMAIN=%TEXDIR%texmf
set TEXMFDIST=%TEXDIR%texmf-dist
set TEXMFLOCAL=%TEXDIR%texmf-local
set TEXMFHOME=%TEXDIRW%texmf-home
set TEXMFVAR=%TEXDIRW%texmf-var
set TEXMFCONFIG=%TEXDIRW%texmf-config
set TEXBINDIR=%TEXDIR%bin\win32
set platform=win32
path %TEXDIR%bin\win32;%path%

rem use provided Perl

set PERL5LIB=%TEXDIR%tlpkg\installer\perllib
"%TEXDIR%tlpkg\installer\perl" "%TEXDIR%install-tl" --portable
if not errorlevel 1 goto doit
echo Initialization of TeXLive failed!
pause
exit

:doit
set PROMPT=TL $P$G
%COMSPEC% /k

rem ===============================================

-- 
Siep Kroonenberg


More information about the tex-live mailing list